Olivier
13f35677be
Move Home Manager module defaults from a centralized `desktop-home-defaults.nix` file into their respective `wisdom` slices. This change aligns with the updated documentation regarding module ownership, where defaults live with the option that owns them rather than in a shared defaults file. Additionally, update `docs/conventions.md` to reflect this new pattern for defining `mkEnableOption` defaults and move base git/encryption configurations into the core `wisdom` module. - Delete `modules/hosts/desktop-home-defaults.nix` - Update `modules/wisdom/default.nix` to include shared git and package defaults - Add `default = ...` to `mkEnableOption` in various `wisdom` modules - Update `docs/conventions.md` with new HM slice guidelines
42 lines
1.3 KiB
Nix
42 lines
1.3 KiB
Nix
{ ... }: {
|
|
flake.homeManagerModules.wisdomTerminalsKitty =
|
|
{ config, lib, pkgs, ... }:
|
|
let
|
|
root = config.chiasson.home;
|
|
cfg = config.chiasson.home.terminals.kitty;
|
|
kittyShellExe =
|
|
if config.programs.fish.enable or false then
|
|
lib.getExe config.programs.fish.package
|
|
else if config.programs.bash.enable or false then
|
|
lib.getExe config.programs.bash.package
|
|
else
|
|
"${pkgs.bash}/bin/bash";
|
|
in
|
|
{
|
|
options.chiasson.home.terminals.kitty.enable = lib.mkEnableOption ''
|
|
Kitty + DMS includes; activation strips `*-theme.auto.conf` so matugen colors stick.
|
|
'' // {
|
|
default = true;
|
|
};
|
|
|
|
config = lib.mkIf (root.enable && cfg.enable) {
|
|
programs.kitty = {
|
|
enable = true;
|
|
extraConfig = ''
|
|
shell ${kittyShellExe}
|
|
include dank-tabs.conf
|
|
include dank-theme.conf
|
|
allow_remote_control yes
|
|
listen_on unix:@kitty
|
|
'';
|
|
};
|
|
|
|
home.activation.kittyRemoveAutoThemes = lib.hm.dag.entryAfter [ "writeBoundary" ] ''
|
|
rm -f "$HOME/.config/kitty/dark-theme.auto.conf" \
|
|
"$HOME/.config/kitty/light-theme.auto.conf" \
|
|
"$HOME/.config/kitty/no-preference-theme.auto.conf"
|
|
'';
|
|
};
|
|
};
|
|
}
|