{ ... }: {
  flake.homeManagerModules.wisdomTerminalsKitty =
    { config, lib, pkgs, ... }:
    let
      root = config.chiasson.home;
      cfg = config.chiasson.home.terminals.kitty;
      kittyShellExe =
        if config.programs.fish.enable or false then
          lib.getExe config.programs.fish.package
        else if config.programs.bash.enable or false then
          lib.getExe config.programs.bash.package
        else
          "${pkgs.bash}/bin/bash";
    in
    {
      options.chiasson.home.terminals.kitty.enable = lib.mkEnableOption ''
        Kitty + DMS includes; activation strips `*-theme.auto.conf` so matugen colors stick.
      '';

      config = lib.mkIf (root.enable && cfg.enable) {
        programs.kitty = {
          enable = true;
          extraConfig = ''
            shell ${kittyShellExe}
            include dank-tabs.conf
            include dank-theme.conf
            allow_remote_control yes
            listen_on unix:@kitty
          '';
        };

        home.activation.kittyRemoveAutoThemes = lib.hm.dag.entryAfter [ "writeBoundary" ] ''
          rm -f "$HOME/.config/kitty/dark-theme.auto.conf" \
                "$HOME/.config/kitty/light-theme.auto.conf" \
                "$HOME/.config/kitty/no-preference-theme.auto.conf"
        '';
      };
    };
}