Rebase to flake parts #8

2026-05-08 21:48:22 -03:00
parent f98606dcce
commit 34b89af77f
30 changed files with 3567 additions and 1 deletions
@@ -0,0 +1,52 @@
+{ inputs, ... }: {
+  flake.nixosModules.desktopWallpapers =
+    { config, lib, pkgs, ... }:
+    let
+      cfg = config.chiasson.desktop.wallpapers;
+      d = config.chiasson.desktop;
+      guiEnabled = d.hyprland.enable || d.niri.enable || d.plasma.enable;
+
+      wallpaperDir = pkgs.stdenvNoCC.mkDerivation {
+        pname = "nixos-v2-wallpapers";
+        version = "0.1";
+        src = builtins.path {
+          path = cfg.source;
+          name = "wallpapers-src";
+        };
+        dontConfigure = true;
+        dontBuild = true;
+        installPhase = ''
+          mkdir -p "$out/share/wallpapers"
+          find "$src" -mindepth 1 -maxdepth 1 ! -name .git -exec cp -a {} "$out/share/wallpapers/" \;
+        '';
+      };
+
+      installPath = "${wallpaperDir}/share/wallpapers";
+    in
+    {
+      options.chiasson.desktop.wallpapers = {
+        enable = lib.mkEnableOption ''
+          Copy `source` into the store; sets `NIXOS_V2_WALLPAPERS` and `/etc/wallpapers`.
+        '' // {
+          default = true;
+        };
+
+        source = lib.mkOption {
+          type = lib.types.path;
+          default = inputs.wallpapers;
+          description = ''
+            Directory copied into the store. Default: `inputs.wallpapers`
+            (`git+https://git.chiasson.cloud/Olivier/wallpapers`, pinned in `flake.lock`).
+          '';
+        };
+      };
+
+      config = lib.mkIf (guiEnabled && cfg.enable) {
+        environment = {
+          variables.NIXOS_V2_WALLPAPERS = installPath;
+          sessionVariables.NIXOS_V2_WALLPAPERS = installPath;
+          etc."wallpapers".source = installPath;
+        };
+      };
+    };
+}